Re: Base Conversion

[Prev][Next][Index][Thread]

Re: Base Conversion

>   jwardell@aol.com (JWardell) writes:
>  Does anyone have or know of good bes conversion programs, for the 82, 83,
>  or 92? It would be great if it could do simple +/-/*// too. Thanks.
        [snip]
>                            -Josh Wardell
>  http://users.aol.com/jwardell/JWardell.html
>
>>>>
This TI-83 program converts numbers from one base to
another using conventional ASCII string notation.
----begin documentation----
This program is loosely based on BASECONV for the TI-82
by Mikael Bonnier (mikaelb@df.lth.se). It makes use of
the TI-83's string functions so that input and output
appear in normal alphanumeric notation. The length is
due to thorough validation of all input. To save time,
strings are not used for base 10 input and output.


When started, the program prompts for input and output
bases, which are entered as decimal numbers no smaller
than 2 and no larger than 36. It then prompts for N, the
number to be converted. N is entered as a string of
alphanumeric digits in the input base notation, so that
if the input base is 16, digits 0 through 9 and A through
F may be input. For base 36, all letters including Z can
be used. If the input contains invalid digits, the first
is flagged. When the input is valid, the output appears
on the next line in the output base notation. Then, when
ENTER is pressed, the program is ready to accept another
input in the same base. To quit, enter 0 (which is the
same in any base).


The program cleans up after itself, deleting all variables
used (I, J, N - R, Str1 - Str9) except:
        I, which contains the input base,
        O, which contains the output base,
        N, which contains the converted number (base 10)
        Str1, which contains the input (if not base 10), and
        Str2, which contains the output (if not base 10).


Thus, after exiting the program, it is possible to store the
converted number N in a different variable. For example, to
store it as M, one would key in N\->\M. If, after converting
M and N, the program is restarted with 10 as the input base,
the number to be converted can be entered as an expression,
like M+N, M-N, MN, or int(M/N). More complex expressions can
be entered in the same way. This allows the results of
calculations to be displayed in the output base.
----begin ASCII----
\start83\
\comment=Base Conversion: 2<=Base<=36
\name=BASECNV
\file=BASECNV.TXT
"0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"\->\Str3
" INPUT BASE: "\->\Str4
"OUTPUT BASE: "\->\Str5
"PRESS ENTER"\->\Str6
"ERROR: "\->\Str7
"NON-INT"\->\Str8
0\->\P
Lbl A
ClrHome
Disp "BASE CONVERSION"
Disp ""
If P=0
Then
Input Str4,I
Goto B
Else
Disp ""
Output(3,1,Str4)
Output(3,14,I)
End
If P=1
Then
Input Str5,O
Goto B
Else
Disp ""
Output(4,1,Str5)
Output(4,14,O)
End
Disp "N OR 0 TO QUIT:"
If I=10
Then
DelVar Str1
Input "",R
If R=0
Goto Z
If R<0 or R\!=\int(R)
Then
If R\!=\int(R)
Output(7,1,Str7+Str8)
If R<0
Output(7,1,Str7+"N < 0  ")
Output(8,1,Str6)
Pause
Goto A
End
Else
Input "",Str9
If Str9="0"
Goto Z
Str9\->\Str1
0\->\R
For(J,1,length(Str1))
inString(Str3,sub(Str1,J,1))-1\->\Q
If Q<0 or Q\>=\I
Then
Output(7,1,"INVALID DIGIT:  ")
Output(7,16,sub(Str1,J,1))
Output(8,1,Str6)
Pause
Goto A
End
IR+Q\->\R
End
End
Output(5,1,"               ")
R\->\N
If O=10
Then
DelVar Str2
Output(7,1,N)
Else
" "\->\Str2
For(J,1,int(round(ln(R)/ln(O),7))+1)
sub(Str3,round(OfPart(R/O),0)+1,1)+Str2\->\Str2
int(R/O)\->\R
End
sub(Str2,1,length(Str2)-1)\->\Str2
Output(7,1,Str2)
End
Output(8,1,Str6)
Pause
Goto A
Lbl B
If P=0
I\->\O
If O\>=\2 and O\<=\36 and O=int(O)
Then
P+1\->\P
Else
If O\!=\int(O)
Output(5+P,1,Str7+Str8)
If O<2
Output(5+P,1,Str7+"BASE < 2")
If O>36
Output(5+P,1,Str7+"BASE > 36")
Output(6+P,1,Str6)
Pause
End
Goto A
Lbl Z
DelVar J
DelVar P
DelVar Q
DelVar R
DelVar Str3
DelVar Str4
DelVar Str5
DelVar Str6
DelVar Str7
DelVar Str8
DelVar Str9
ClrHome
\stop83\
----begin uue----
begin 664 basecnv.83p
M*BI423@S*BH:"@!"87-E($-O;G9E<G-I;VXZ(#(\/4)A<V4\/3,V````````
M``````````!A`PL`4@,%0D%314-.5@!2`U`#*C`Q,C,T-38W.#E!0D-$149'
M2$E*2TQ-3D]045)35%565UA96BH$J@(_*BE)3E!55"E"05-%/BDJ!*H#/RI/
M5510550I0D%313XI*@2J!#\J4%)%4U,I14Y415(J!*H%/RI%4E)/4CXI*@2J
M!C\J3D].<4E.5"H$J@<_,`10/]9!/^$_WBI"05-%*4-/3E9%4E-)3TXJ/]XJ
M*C_.4&amp;HP/\\_W*H#*TD_UT(_T#_>*BH_X#,K,2NJ`Q$_X#,K,30K21$_U#_.
M4&amp;HQ/\\_W*H$*T\_UT(_T#_>*BH_X#0K,2NJ!!$_X#0K,30K3Q$_U#_>*DXI
M3U(I,"E43RE154E4/BH_SDEJ,3`_SS^[5*H`/]PJ*BM2/\Y2:C`_UUH_SE)K
M,#Q2;[%2$3_//\Y2;[%2$3_@-RLQ*ZH&amp;<*H'$3_.4FLP/^`W*S$KJ@9P*DXI
M:RDP*2DJ$3_@."LQ*ZH%$3_8/]=!/]0_T#_<*BHKJ@@_SJH(:BHP*C_76C^J
M"`2J`#\P!%(_TTHK,2N[*ZH`$1$_NP^J`BN[#*H`*THK,1$1<3$$43_.46LP
M/%%N23_//^`W*S$K*DE.5D%,240I1$E'250^*2DJ$3_@-RLQ-BN[#*H`*THK
M,1$1/^`X*S$KJ@41/]@_UT$_U#])4G!1!%(_U#_4/^`U*S$K*BDI*2DI*2DI
M*2DI*2DI*2H1/U($3C_.3VHQ,#_//[M4J@$_X#<K,2M.$3_0/RHI*@2J`3_3
M2BLQ*[$2OE(1@[Y/$2LW$1%P,1$_NPRJ`BL23[I2@T\1*S`1<#$K,1%PJ@$$
MJ@$_L5*#3Q$$4C_4/[L,J@$K,2N[*ZH!$7$Q$02J`3_@-RLQ*ZH!$3_4/^`X
M*S$KJ@41/]@_UT$_UD(_SE!J,#])!$\_SD]N,D!/;3,V0$]JL4\1/\\_4'`Q
M!%`_T#_.3V^Q3Q$_X#5P4"LQ*ZH&amp;<*H'$3_.3VLR/^`U<%`K,2NJ!G`J0D%3
M12EK*3(J$3_.3VPS-C_@-7!0*S$KJ@9P*D)!4T4I;"DS-BH1/^`V<%`K,2NJ
M!1$_V#_4/]=!/]9:/[M42C^[5%`_NU11/[M44C^[5*H"/[M4J@,_NU2J!#^[
65*H%/[M4J@8_NU2J!S^[5*H(/^%/$@``


end


                                        Harry Elam
References: