Re: A83: On button Interupt

[Prev][Next][Index][Thread]

Re: A83: On button Interupt


--- Ryan Cullan <childofdakorn14@hotmail.com> wrote:
> 
> hi everybody. This is Ryan Cullan again. I'm a real
> newbie to Allk ASM in 
> total. But can someone help me for one thing...  can
> sombody tell me where i 
> can get a souce code for an interupt so that the ON
> button wont work or if 
> someone can write one that would be great thanx!
> 

  Actually, I think what you are wanting, and no one
is giving you, is this.  It should work, only you'll
have to run a program with "IM 1" to turn it off.  

Jimmy Conner


.nolist
#define 	equ 		.equ
#define 	EQU 		.equ
#define 	END 		.end

#include "ti83asm.inc"
#include "tokens.inc"
.list

.org    $9327
	di
	im      1
	ld      hl,$8300
	ld      de,$8301
	ld      (hl),$84
	ld      bc,$0100
	ldir        

	ld      hl,interrupt_start
	ld      de,$8484
	ld      bc,interrupt_end-interrupt_start
	ldir                            

	ld      a, $83
	ld      i, a
	im      2           
	ei
	ret

interrupt_start:      ; Real simple routine
	ex	af, af'
	in	a, (3)
	rra
	jr	nc, not_on
	res	3, (iy+18)  ; Res 2nd-Shift Mode
not_on:
	ex	af, af'
	jp	$0038
interrupt_end:

.end
end






=====
»»»»»»»»»»»»»»»«««««««««««««««
»      TIMagic@goatse.cx     «
»  http://www.zed80asm.org   «
» http://www.timagic.cjb.net «
»»»»»»»»»»»»»»»«««««««««««««««
__________________________________________________
Do You Yahoo!?
Talk to your friends online with Yahoo! Messenger.
http://im.yahoo.com
Follow-Ups: