Re: A82: sources

[Prev][Next][Index][Thread]

Re: A82: sources


Dines has a good Asm school (where's his site?)
As for utilities go to www.ticalc.org/pub (click on the utilities link)
Info, as in rom/ram/ports?  Then www.ticalc.org/pub/text (just get the
ti82 text files)
Linking, as in calc to calc (2 player games)?  Then scroll down

ti-files also has all or most of these files too.  (see! i'm not picking
favorites!)

here's LINKROUT.H, a good link routine used in Ztetris for the 85/6
(modified to accomodate the 82)

;
; SOME VERY NICE LINK ROUTINES MADE BY PASCAL BOURON
;
; Jimmy made modifications so it fits ZTetris
; I (Greg) made some to fit the 82.

; a = byte to send

ReceiveByte:
	 ld hl,0
	 ld (lcounter),hl
	 ld e,1			 ; for the OR
	 ld c,0			 ; byte receive
	 ld b,8			 ; counter
	 ld a,$C0
	 out (0),a
rb_w_Start:
	 in a,(0)
	 and 3
	 cp 3
	 jr nz,rb_get_bit
	 call Test_ON
	 jr rb_w_Start
rb_get_bit:
	 cp 2
	 jr z,rb_receive_zero
	 ld a,c
	 or e
	 ld c,a
	 ld a,$D4
	 out (0),a
	 jr rb_waitStop
rb_receive_zero:
	 ld a,$E8
	 out (0),a
rb_waitStop:
	 call Test_ON
	 in a,(0)
	 and 3
	 jr z,rb_waitStop
	 ld a,$c0
	 out (0),a
	 rl e
	 djnz rb_w_Start
	 ld a,c
	 ret

SendByte:
	 ld hl,0
	 ld (lcounter),hl
	 ld b,8
	 ld (sbyte),a
	 ld c,a			 ;byte to send
	 ld a,$C0
	 out (0),a
w_setport3:
	 in a,(0)
	 and 3
	 cp 3
	 jr z,calc_bit
	 call SendTest_ON
	 jr w_setport3
calc_bit:
	 ld a,c
	 and 1
	 jr z,send_one
send_zero:
	 ld a,$E8
	 out (0),A
	 jr wait_setport
send_one:
	 ld a,$D4
	 out (0),A
	wait_setport:
	 call SendTest_ON
	 in a,(0)
	 and 3
	 jr nz,wait_setport
	 ld a,$C0
	 out (0),A
	 srl c
	 djnz w_setport3
	 xor a
	 ld (sbyte),a
	 ret

Test_ON:
	 ld a,(lcounter)
	 inc a
	 ld (lcounter),a
	 cp 255
	 ret nz
	 pop hl
	 xor a
	 ret

SendTest_ON:
	 ld a,(hsflag)
	 or a
	 jr z,LongWait
	 call GET_KEY
	 cp $37
	 ret nz
	 pop hl
	 pop hl
	 jp Quit
LongWait:
	 ld hl,(lcounter)
	 inc hl
	 ld (lcounter),hl
	 ld de,$3FFF
	 call CP_HL_DE
	 ret nz
	 pop hl
	 ret


On Tue, 3 Mar 1998 20:42:50 -0500 larry1492@juno.com (Larry G Currie)
writes:
> Sorry if this message overlaps suggestions.  C'mon guys, where's some 
>sites I should check out that have asm lessons/info/utilities/linking 
>information?  I really want to learn, but need sites by thursday 
>before I lose internet access for the week I have free time.   Please 
>please
>please.
>~Larry C
>Larry1492@juno.com  

_____________________________________________________________________
You don't need to buy Internet access to use free Internet e-mail.
Get completely free e-mail from Juno at http://www.juno.com
Or call Juno at (800) 654-JUNO [654-5866]
References: